*Copyright @ www.mycsg.in;

Creating a sample dataset

data series01;
   length var group $10;
   var="%"; group="Symbol"; output;
   var="$"; group="Symbol"; output;
   var="1"; group="Digits"; output;
   var="2"; group="Digits"; output;
   var="10"; group="Digits"; output;
   var="101"; group="Digits"; output;
   var="21"; group="Digits"; output;
   var="11"; group="Digits"; output;
   var="a"; group="Lowcase"; output;
   var="ab"; group="Lowcase";output;
   var="A"; group="Uppercase";output;
   var="AB"; group="Uppercase"; output;
   var="b"; group="Lowcase";output;
   var="B"; group="Uppercase"; output;
run;

Understanding sort sequence of character variables in SAS

Create a dataset named series01_sort01 by sortint series01 dataset based on ascending sequence of 'var' variable

Symbols
Digits: Within digits, numbers starting with a digit are grouped together
Upper case letters
Lower case letters

proc sort data=series01 out=series01_sort01;
   by var;
run;

Modifying the sorting sequence of character variables using sortseq=option

Group lower case and upper case letter together

LINGUISTIC option can be used to sort the lower case and upper case letters together

proc sort data=series01 out=series01_sort02 sortseq=linguistic;
   by var;
run;

Group lower case and upper case letter together and give preference to lowercase letters

LINGUISTIC option can be used to sort the lower case and upper case letters together
case_first= suboption can be used provide preference for lower and upper case letter
LOWER option has to be used on case_first= suboption

proc sort data=series01 out=series01_sort03 sortseq=linguistic(case_first=lower);
   by var;
run;

Group lower case and upper case letter together and give preference to upper case letters

LINGUISTIC option can be used to sort the lower case and upper case letters together
case_first= suboption can be used provide preference for lower and upper case letter
UPPER option has to be used on case_first= suboption

proc sort data=series01 out=series01_sort04 sortseq=linguistic(case_first=upper);
   by var;
run;

Sort character digits based on their numeric value

LINGUISTIC option can be used to sort the lower case and upper case letters together
NUMERIC_COLLATION= suboption can be used provide preference for lower and upper case letter
ON option has to be used on numeric_collation= suboption

proc sort data=series01 out=series01_sort05 sortseq=linguistic(numeric_collation=on);
   by var;
run;