← SASnRList Files with Metadata: Size, Created and Modified Time

Introduction

The previous lesson (8100) listed files by name; this one adds the metadata columns we usually want alongside the name: size, creation time, modification time.
Typical uses: spot stale files that have not been updated in weeks, flag unexpectedly large outputs, audit the folder for completeness.
SAS needs a nested open — fopen on each file produced by dopen/dread — and reads metadata with fsize() and finfo().
Tidyverse uses the fs package: dir_ls() for the path list and file_info() for the metadata in one tidy call.
Base R uses list.files() + file.info(); no extra package required.
This lesson produces a file-list data frame with size, modified time, and created time per file.

List Files with Metadata: Size, Created and Modified Time

SAS (Base SAS)+

filename mydir "C:\Users\curio\Desktop\Rough";

data file_list;
  length full_filename filename folder basename extension $256;
  length file_size file_created file_modified $64;

  folder = pathname("mydir");
  did = dopen("mydir");

  if did > 0 then do;
    nfiles = dnum(did);
    do i = 1 to nfiles;
      filename = dread(did, i);
      full_filename = cats(folder, "\", filename);

      rc1 = filename("fref", full_filename);
      if rc1 = 0 then do;
        fid = fopen("fref");
        if fid > 0 then do;
          file_size = strip(put(fsize(fid), best.));
          file_modified = finfo(fid, "Last Modified");
          file_created  = finfo(fid, "Create Time");
          rc2 = fclose(fid);
        end;
      end;

      if index(filename, ".") then do;
        extension = scan(filename, -1, ".");
        basename = substr(filename, 1, length(filename) - length(extension) - 1);
      end;
      else do;
        extension = "";
        basename = filename;
      end;

      output;
    end;
    rc = dclose(did);
  end;

  drop did nfiles i rc rc1 rc2 fid;
run;

The SAS metadata version builds on the 8100 pattern and adds a nested fopen()/fclose() step per file.
We loop the directory with dopen / dnum / dread as before, storing the full path in full_filename.
For each file, filename("fref", full_filename) assigns a filename reference, and fopen("fref") opens the file handle for metadata queries.
fsize(fid) returns the size in bytes; we wrap it in put(..., best.) plus strip() for a clean character string.
finfo(fid, "Last Modified") and finfo(fid, "Create Time") pull the timestamps; the attribute names are operating-system dependent.
fclose(fid) closes the file handle before we move to the next entry; dclose(did) closes the directory handle at the end.
The basename/extension split works exactly as in lesson 8100; the drop list removes the helper IDs and return codes.
We run and check FILE_LIST has file size plus creation and modified timestamps per row.

R (tidyverse)+

library(tidyverse)
library(fs)

folder_path <- "C:/Users/curio/Desktop/Rough"

file_paths <- dir_ls(path = folder_path, type = "file")

file_list <- tibble(
  full_filename = file_paths,
  filename = path_file(file_paths),
  folder = folder_path,
  basename = tools::file_path_sans_ext(filename),
  extension = tools::file_ext(filename),
  file_size = file_info(file_paths)$size,
  modified_time = file_info(file_paths)$modification_time,
  created_time = file_info(file_paths)$change_time
)

print(file_list)

The fs package turns this into a compact call by combining path listing and metadata retrieval.
dir_ls(path = folder_path, type = "file") returns the full paths of every file in the folder — skipping sub-directories.
path_file(file_paths) extracts just the file name portion from each path, filling the filename column.
tools::file_path_sans_ext() and tools::file_ext() split basename from extension, just as in lesson 8100.
file_info(file_paths) returns a tibble with size, modification time, change time, and permission bits for each file — we pull out the columns we need with $size, $modification_time, and $change_time.
Every piece goes into one tibble() call, giving a single data frame with name, folder, basename, extension, and metadata.
We run and verify each row shows the file name with its size and timestamps lined up correctly.

Happy learning!

Search lessons

Introduction

List Files with Metadata: Size, Created and Modified Time